/* ----------------------------------------------
Computing Kaizen Studio
Advanced Studio VI Spring 2010
Columbia University GSAPP

Informational Body
Code by Esther Cheung
http://www.arch.columbia.edu/
http://proxyarch.com/kaizen

This work is licensed under a Creative Commons 
Attribution-Noncommercial-Share Alike 3.0 License
-----------------------------------------------*/

Point [] allvoxels;
float unit = 1;
float range;
float threshold;
boolean changing = false;
float thresholdActual;
PVector goal;

void setup(){
  goal = new PVector();
  thresholdActual = 0.0;

  size(600, 450, P3D);
  randomSeed(0);
  colorMode(HSB);

  //load raw data
  String [] rawdata = loadStrings("07.txt");

  //convert to float data
  float [] floatdata = new float [rawdata.length];
  for (int i=0; i<rawdata.length; i++){
    floatdata[i] = float (rawdata[i]);
  }

  //make point objects
  allvoxels = new Point [floatdata.length/4];
  for (int i=0; i<floatdata.length/4; i++){
    allvoxels [i] = new Point( new PVector (floatdata[i*4], floatdata[i*4+1], floatdata[i*4+2]), floatdata[i*4+3]/1157);
  }

  float xmin, ymin, zmin, amin;
  xmin = ymin = zmin = amin = 1000.0;
  float xmax, ymax, zmax, amax;
  xmax = ymax = zmax = amax = 0.0;

  for(int i=0; i<allvoxels.length; i++){
    xmax = max(xmax, allvoxels[i].pos.x);
    ymax = max(ymax, allvoxels[i].pos.y);
    zmax = max(zmax, allvoxels[i].pos.z);
    xmin = min(xmin, allvoxels[i].pos.x);
    ymin = min(ymin, allvoxels[i].pos.y);
    zmin = min(zmin, allvoxels[i].pos.z);
    amin = min(amin, allvoxels[i].a);
    amax = max(amax, allvoxels[i].a);
  }
}


void draw(){

  background(230);
  PVector cam = new PVector(600,1000,0);
  float camlen = 500;

  camera(sin(radians(frameCount/3.0))*camlen+cam.x, cos(radians(frameCount/3.0))*camlen+cam.y, camlen, cam.x, cam.y, 0, 0,0,-1);
  scale(10,10,10);
  lights();
  range = .1;
  threshold = (sin(radians(frameCount))+1)/3.0 + .2;

  for (int i=0; i<allvoxels.length; i++){
    allvoxels[i].figureStatus(threshold, range);    
  }

  float touchThresh = 75; 
  PVector blobCenter = new PVector(mouseX, mouseY);
  for(int j=0; j<allvoxels.length; j++){
    if(allvoxels[j].plotStatus){
      PVector yourObject = allvoxels[j].pos;

      // translating 3D point to Screen Point
      float sx = screenX(yourObject.x, yourObject.y, yourObject.z);
      float sy = screenY(yourObject.x, yourObject.y, yourObject.z);
      PVector screenPoint = new PVector(sx,sy);
      if(screenPoint.dist(blobCenter) < touchThresh){
        allvoxels[j].touched = true;
      }
    }
  }

  // actually plot them
  for (int i=0; i<allvoxels.length; i++){
    allvoxels[i].plot(threshold, range);    
  }

  //plot blobs
  camera();
  fill(200);
  noStroke();
  //ellipse(blobCenter.x, blobCenter.y, 20,20);

}