/* ----------------------------------------------
Computing Kaizen Studio
Advanced Studio VI Spring 2010
Columbia University GSAPP

Subdividing Bodies
Code by Nikolas Stutzin
http://www.arch.columbia.edu/
http://proxyarch.com/kaizen

This work is licensed under a Creative Commons 
Attribution-Noncommercial-Share Alike 3.0 License
-----------------------------------------------*/

import traer.physics.*;
float touchThresh = 50;

Graph myGraph;
ParticleSystem physics;
int counter;
PVector center;
PVector[] arrPoints;

int condist = 100;
int seeds = 12;
float area = 10000;
boolean changed = true;


void setup(){

  size(600,450, P3D);
  reset();

}

void reset(){

  counter = 0;
  physics = new ParticleSystem(0,0,.5, 2);
  myGraph = new Graph( physics );

  for(int i=0; i<seeds; i++){
    Node theNode = myGraph.addNode( counter+"", 1.0, random(-300,300), random(-300,300), i*0.1, area, i, i*0.1);
    theNode.fix();
    counter++;
  }

  Node[] connections = myGraph.getNodes();
  for(int j=0; j<connections.length; j++){
    Node theNode = connections[j];
    theNode.branch(2);
  }

}




void draw(){

  background(200);
  lights();
  float camlen = 500;
  camera( sin(radians(frameCount*.2))*camlen, cos(radians(frameCount*.2))*camlen, camlen,   0, 0, 50,    0,0,-1);
  physics.tick(.1);
  myGraph.update();
  myGraph.plot3D(1);


  PVector blobCenter = new PVector(mouseX, mouseY);
  Node[] connections = myGraph.getNodes();
  for(int j=0; j<connections.length; j++){
    Node theNode = connections[j];
    if (theNode.connections.length < 2 && theNode.sm > 100){
      float sx = screenX(theNode.x, theNode.y, theNode.z);
      float sy = screenY(theNode.x, theNode.y, theNode.z);
      PVector screenPoint = new PVector(sx,sy);
      if(screenPoint.dist(blobCenter) < touchThresh){
        theNode.branch(2);
      }
    }
  }

  //CONNECTIONS
  Node[] current = new Node[0];
  for(int i=0; i<connections.length; i++){
    Node theNode = connections[i];
    if (theNode.connections.length < 2){
      current = (Node[]) append (current, theNode);  
    }
  }
  if(frameCount % 30 == 0){
    for(int i=0; i<current.length; i++){
      Node theNode = current[i];
      for(int j=0; j<current.length; j++){
        Node theOtherNode = current[j];
        boolean seed = theNode.p.isFixed();
        if ((i!=j) && (seed == false)){
          float d = dist (theNode.x, theNode.y,theNode.z, theOtherNode.x,theOtherNode.y,theOtherNode.z);
          if (d < condist && theNode.tree!=theOtherNode.tree){
            theNode.connect (theOtherNode, 1, 30, true);
            theOtherNode.connect (theNode, 1, 30, false);
            theNode.connect++;
          }
        }
      }
    }
  }

  // Resetting camera to top and drawing blobs - KEEP FOR NOW
  camera();
  fill (255,200);
  noStroke();
  ellipse(blobCenter.x, blobCenter.y, 50, 50);

}

void mousePressed(){
   reset(); 
}