import quickhull3d.*;

class ConvexHull3D {

  //PROPERTIES
  QuickHull3D qHull;
  PVector[] pvectsForHull;
  Point3d[] ptsForHull;
  Point3d[] hullVertices;
  PVector[] hullPVects;
  int[][] faceIndices;
  Face[] arrFaces;

  //CONSTRUCTOR
  ConvexHull3D(PVector[] _originalPts){
    qHull = new QuickHull3D();
    pvectsForHull = _originalPts;
    arrFaces = new Face[0];

    //convert PVector[] to Point3d[] for hull
    ptsForHull = new Point3d[0];
    for(int i=0; i<pvectsForHull.length; i++){
      PVector pv = pvectsForHull[i];
      if(pv != null){
        Point3d pt = new Point3d(pv.x, pv.y, pv.z);
        ptsForHull = (Point3d[]) append(ptsForHull, pt);
      }
    }

    //build hull from original points
    if(ptsForHull.length > 0){
      qHull.build(ptsForHull);
    }

    //extract vertices from hull
    hullVertices = qHull.getVertices();
    hullPVects = new PVector[hullVertices.length];
    for(int i=0; i <hullVertices.length; i++){ 
      Point3d pt = hullVertices[i];
      hullPVects[i] = new PVector((float) pt.x, (float) pt.y, (float) pt.z);
    }

    //extract faces from hull
    faceIndices = qHull.getFaces();
    for(int i=0; i<faceIndices.length; i++){
      Face addFace = new Face(hullPVects, faceIndices[i][0], faceIndices[i][1], faceIndices[i][2]);
      arrFaces = (Face[]) append(arrFaces, addFace);
    }
  }

  //METHODS
  void plot(){
    for(int i=0; i<arrFaces.length; i++){
      Face theFace = arrFaces[i];
      //theFace.plotEdges();
      theFace.plotFaces();
    }
  }

}

class Face {
  //PROPERTIES
  PVector pvA, pvB, pvC;

  //CONSTRUCTOR  
  Face(PVector[] hullPVects, int indexA, int indexB, int indexC){
    pvA = hullPVects[indexA];
    pvB = hullPVects[indexB];
    pvC = hullPVects[indexC];
  }

  //METHODS
  void plotEdges(){
    line(pvA.x, pvA.y, pvA.z, pvB.x, pvB.y, pvB.z);
    line(pvB.x, pvB.y, pvB.z, pvC.x, pvC.y, pvC.z);
    line(pvC.x, pvC.y, pvC.z, pvA.x, pvA.y, pvA.z);
  }

  void plotFaces(){
    beginShape();
    vertex(pvA.x, pvA.y, pvA.z);
    vertex(pvB.x, pvB.y, pvB.z);
    vertex(pvC.x, pvC.y, pvC.z);
    endShape(CLOSE);
  }

}