class Network {

  //PROPERTIES
  Node[] arrNodes;
  int count;
  int num_I, num_O, num_P, numNodes;
  float ratio_I, ratio_O, ratio_P, maxRatio;
  float avgTransparency;
  Boolean blnLoop, blnActive;
  color clr;

  //CONSTRUCTOR
  Network(Node[] _arrNodes){
    arrNodes = _arrNodes;
    numNodes = arrNodes.length;
    blnLoop = false;
    blnActive = true;
    clr = getFillClr();
    this.update();
  }

  //METHODS
  color getFillClr(){
    float hueValue = 0;
    color clrLerp = arrNodes[0].clr;
    for(int i=1; i<numNodes; i++){
      Node addNode = arrNodes[i];
      color nodeClr = addNode.clr;
      if( (hue(nodeClr) == 0) && (hue(clrLerp) >= 50) ){
        nodeClr = color(getColour("red"));
      }
      clrLerp = lerpColor(clrLerp, nodeClr, (1.0/(i+1)));
      hueValue += hue(arrNodes[i].clr);
    }
    hueValue = hueValue/arrNodes.length;
    color fillClr = color(hueValue, 50, 100, 100);
    clrLerp = color(hue(clrLerp), 50, 100, 100);
    return clrLerp;
  }
  
  void update(){
    num_I = 0;
    num_O = 0;
    num_P = 0;
    for(int i=0; i<arrNodes.length; i++){
      if( arrNodes[i].type == 1 )  num_I++;
      else if( arrNodes[i].type == 2 )  num_O++;
      else if( arrNodes[i].type == 3 )  num_P++;
    }
    ratio_I = float(num_I)/float(numNodes);
    ratio_O = float(num_O)/float(numNodes);
    ratio_P = float(num_P)/float(numNodes);
    maxRatio = ratio_I;
    if( ratio_O > maxRatio )  maxRatio = ratio_O;
    if( ratio_P > maxRatio )  maxRatio = ratio_P;
    //update colour
    clr = getFillClr();
    //update transparency of network
    avgTransparency = 0;
    for(int i=0; i<arrNodes.length; i++){
      avgTransparency += arrNodes[i].transparency;
    }
    avgTransparency = round(avgTransparency/numNodes);
  }
  
  void addNode(Node _node){
    arrNodes = (Node[]) append(arrNodes, _node);
    numNodes++;
    this.update();
  }
  
  void insertNode(Node _node){
    ArrayList AL = new ArrayList();
    for(int i=0; i<arrNodes.length; i++){
      AL.add(arrNodes[i]);
    }
    AL.add(AL.size()-1, _node);
    for(int i=0; i<AL.size()-1; i++){
      arrNodes[i] = (Node) AL.get(i);
    }
    Node last = (Node) AL.get(AL.size()-1);
    arrNodes = (Node[]) append(arrNodes, last);
    numNodes++;
    this.update();
  }

  void plot(){
    for(int i=0; i<arrNodes.length-1; i++){
      line(arrNodes[i].x, arrNodes[i].y, arrNodes[i].z, arrNodes[i+1].x, arrNodes[i+1].y, arrNodes[i+1].z);
    }
  }

  void plotLoop(){
    for(int i=0; i<arrNodes.length; i++){
      if(i == arrNodes.length - 1){
        line(arrNodes[i].x, arrNodes[i].y, arrNodes[i].z, arrNodes[0].x, arrNodes[0].y, arrNodes[0].z);
      }
      else{
        line(arrNodes[i].x, arrNodes[i].y, arrNodes[i].z, arrNodes[i+1].x, arrNodes[i+1].y, arrNodes[i+1].z);
      }
    }
  }
  
}